* #################################################
* L. CHAMPANEY
*
* Mines-PlaqueTrouee.dgibi
* Exemple de demonstration de Vibrations Libres
*
*   Plaque Trouee 
*
* #################################################
OPTI DIME 3 ELEM TRI3 trac open;
*
* Parametres
Lo1 = 1.;
La1 = 0.4;
Ep1 = 0.01;
Ra1 = 0.1 ;
* Materiau
E1 = 2.1E11;
NU1 = 0.3;
RO1 = 7.8E3;
*
DENS 0.025;
*
P1 = 0.  0.  0. ;
P2 = Lo1 0.  0. ;
P3 = Lo1 La1 0. ;
P4 = 0.  La1 0. ;
*
C1 = (Lo1 / 2.) (La1 / 2.) 0.;
P5 = C1 PLUS (Ra1 0.  0.);
P6 = C1 MOIN (0.  Ra1 0.);
P7 = C1 PLUS (0.  Ra1 0.);
*
L1 = D P1 P2; L2 = D P2 P3;
L3 = D P3 P4; L4 = D P4 P1;
L0 = CER3 P5 P6 P7;
L5 = CERC L0 C1;
*
CONT1 = L1 ET L2 ET L3 ET L4 ET L5;
SURF1 = SURF CONT1 PLANE;
*
MOD1 = MODE SURF1 MECANIQUE ELASTIQUE COQ3;
MAT1 = MATE MOD1  'YOUN' E1 'NU' NU1 'RHO' RO1 'EPAI' Ep1;
*
RIG1 = RIGI MOD1 MAT1;
MAS1 = MASS MOD1 MAT1;
*
CLIM1 = BLOQ DEPL1 ROTA L4;
*
RIGT1 = RIG1 et CLIM1;
MAST1 = MAS1;
*
*
* Base Modale
BMOD1 = VIBR INTERVALLE 0. 10000. 
             'BASSE' 10   
             RIGT1 MAST1 ;
*
* ===============
* Post-Traitement
* ===============
NBMODE1 = DIME BMOD1;
*
REPE BOUC1 NBMODE1;
*
  FREQ1 = TIRE BMOD1 FREQ RANG &BOUC1 ;
  MESS 'Mode ' &BOUC1 ' : ' FREQ1 ' Hz';
  DEPL1 = TIRE BMOD1 DEPL RANG &BOUC1 ;
  DEFO1 = DEFO DEPL1 SURF1 ;
  DEFO0 = DEFO DEPL1 CONT1 0. ROUG;
  TRAC (DEFO1 ET DEFO0) ;
*
FIN BOUC1;

*
* En vibrations forcees : Fonction de transfert
* (dans la gamme 1-500 Hz) mesuree en P2 selon z
* pour une existation en P3 selon z.
*
FTRANZ1 = TRANSFER BMOD1 (PROG 10 * 0.02) UZ P3
         UZ P2 VITE (PROG 1. PAS 0.1 500.) MOPH; 
DESS (extr FTRANZ1 cour 1);
*
*
* En vibrations forcees : Fonction de transfert
* (dans la gamme 1-500 Hz) mesuree en P2 selon x
* pour une existation en P3 selon x.
*
FTRANX1 = TRANSFER BMOD1 (PROG 10 * 0.02) UX P3
         UX P2 VITE (PROG 1. PAS 0.1 500.) MOPH; 
DESS (extr FTRANX1 cour 1);
*

fin;