* #################################################
* L. CHAMPANEY
*
* Mines-Plaque.dgibi
* Exemple de demonstration de Vibrations Libres
*
*   Plaque 
*
* #################################################
OPTI DIME 3 ELEM QUA4 trac open;
*
* Parametres
Lo1 = 1.;
La1 = 0.4;
Ep1 = 0.01;
E1 = 2.1E11;
NU1 = 0.3;
RO1 = 7.8E3;
*
DENS 0.025;
*
P1 = 0.  0.  0. ;
P2 = Lo1 0.  0. ;
P3 = Lo1 La1 0. ;
P4 = 0.  La1 0. ;
*
L1 = D P1 P2; L2 = D P2 P3;
L3 = D P3 P4; L4 = D P4 P1;
*
SURF1 = DALL L1 L2 L3 L4 PLANE;
CONT1 = CONT SURF1;
*
MOD1 = MODE SURF1 MECANIQUE ELASTIQUE COQ4;
MAT1 = MATE MOD1  'YOUN' E1 'NU' NU1 'RHO' RO1 'EPAI' Ep1;
*
RIG1 = RIGI MOD1 MAT1;
MAS1 = MASS MOD1 MAT1;
*
CLIM1 = BLOQ DEPL1 ROTA L4;
*
RIGT1 = RIG1 et CLIM1;
MAST1 = MAS1;
*
*
* Base Modale
BMOD1 = VIBR INTERVALLE 0. 1000. 
             'BASSE' 5   
             RIGT1 MAST1 ;
*
* ===============
* Post-Traitement
* ===============
NBMODE1 = DIME BMOD1;
*
REPE BOUC1 NBMODE1;
*
  DEPL1 = TIRE BMOD1 DEPL RANG &BOUC1 ;
  DEFO1 = DEFO DEPL1 SURF1 ;
  DEFO0 = DEFO DEPL1 CONT1 0. ROUG;
  TRAC (DEFO1 ET DEFO0) ;
*
FIN BOUC1;

fin;