* #################################################
* 
* ENSMP 2002
* Dynamique des Constructions
* L. CHAMPANEY
*
* Mines-Vibr2D.dgibi
* Exemple de demonstration en 2D Dynamique : TABLIER
*
*  
* 
*  ------------------------------------------
*  |                                        |
*  |                                        |
*  |       ----------------------------------
*  |      /
*  |     /
*  |    /
*  |    |
*  |    |
*  |    |
*  |    |
*  ------
*  //////
*
* #################################################
*
OPTI DIME 2 ELEM TRI3 TRAC OPEN;
*
DENS 0.05;
*
* Caracteriques
LONG1 = 1.500;
HAUT1 = 0.700;
EPAI1 = 0.200;
EPAI2 = 0.150;
RRAC1 = 0.300;
*
YOUN1 = 2.E11; CONU1 = 0.3; MVOL1 = 7800.;
*
*
* Geometrie
P1 = 0.    0. ;
P2 = EPAI1 0. ; 
P3 = EPAI1 (HAUT1 - EPAI2 - RRAC1) ; 
P4 = (EPAI1 + RRAC1) (HAUT1 - EPAI2) ; 
C0 = (EPAI1 + RRAC1) (HAUT1 - EPAI2 - RRAC1) ; 
P5 = LONG1 (HAUT1 - EPAI2) ; 
P6 = LONG1 HAUT1 ; 
P7 = 0. HAUT1 ; 
*
L1 = DROI P1 P2; L2 = DROI P2 P3;
L3 = CERC P3 C0 P4;
L4 = DROI P4 P5; L5 = DROI P5 P6;
L6 = DROI P6 P7; L7 = DROI P7 P1;
*
* Contour
CONT1 = L1 ET L2 ET L3 ET L4 ET L5 ET L6 ET L7;
* Surface
SURF1 = SURF CONT1;
*
* Modele de calcul
MODE1 = MODEl SURF1 MECANIQUE ELASTIQUE ;
*
* Loi de comportement
MATE1 = MATR MODE1 'YOUN' YOUN1 'NU' CONU1 'RHO' MVOL1;
*
* Conditions aux limites
CLIM1 = BLOQ DEPL L1;
*
* Matrice de Rigidite
MRIG1 = (RIGI MODE1 MATE1) et CLIM1;
* Matrice de Masse
MMAS1 = MASS MODE1 MATE1;
*
* Deplacement
BMOD1 = VIBR INTERVALLE 0. 10000. 
             'BASSE' 5   
             MRIG1 MMAS1 ;
*
* ===============
* Post-Traitement
* ===============
NBMODE1 = DIME BMOD1;
*
REPE BOUC1 NBMODE1;
*
  DEPL1 = TIRE BMOD1 DEPL RANG &BOUC1 ;
  DEFO1 = DEFO DEPL1 SURF1 ;
  DEFO0 = DEFO DEPL1 SURF1 0. ROUG;
  TRAC (DEFO1 ET DEFO0) CONT1;
*
FIN BOUC1;

fin;